Otherware/Otherware_1_SB_Development.iso/mac/hypercar/xfcn/spttool.cpt/Support Tools eXternals 1.2.5/stack_-1.xml

Extensible Markup Language | 1990-11-14 | 4.0 KB | 16 lines

<?xml version="1.0" encoding="utf-8" ?>
<!DOCTYPE stack PUBLIC "-//Apple, Inc.//DTD stack V 2.0//EN" "" >
<stack>
    <name>in.5</name>
    <id>-1</id>
    <cardCount>53</cardCount>
    <cardID>18126</cardID>
    <listID>2932</listID>
    <cantModify><true /></cantModify>
    <cantDelete><false /></cantDelete>
    <cantAbort><false /></cantAbort>
    <cardSize>
        <width>512</width>
        <height>342</height>
    </cardSize>
    <script>-- Support Tools eXternals 1.2.5
-- copyright © 1989, 1990, Apple Computer, Inc. All rights reserved
-- last modified 7:59 PM 11/13/90 ec
--

on openStack
set userModify to true
end openStack

on openCard
if the short name of this cd = ¬
the short name of cd (number of last cd of this bg) then
hide bg btn "next"
else
show bg btn "next"
end if

if the short name of this cd = ¬
the short name of cd (number of first cd of this bg) then
hide bg btn "previous"
else
show bg btn "previous"
end if
pass openCard
end openCard

function clickLine
-- returns line number clicked on of any field
if the style of the target = "scrolling" then
return ((item 2 of the clickLoc - top of target-4+scroll of target) ¬
div textheight of target) + 1
else
-- clickLine for non scrolling fields
return ((item 2 of the clickLoc - top of target - 4) ¬
div textheight of target) + 1
end if
end clickLine

function selectTheLine whichLine
put line whichLine of target into choice
if choice <> empty then
get offset(return & choice,target) + 1 --include the carriage return
select char it to length(choice) + it of target
end if
return choice
end SelecttheLine

function thisFolderPath -- returns the path to the current folder
put stackPath() into stackFolder
put "" into lastChar
repeat until lastChar = ":"
delete last character of stackFolder
put last character of stackFolder into lastChar
end repeat
return stackFolder
end thisFolderPath

function thisVolumePath
put thisStackPath() into wholePath
return char 1 to offset(":",wholePath) of wholePath
end thisVolumePath

function thisStackPath
return the value of word 2 of long name of this stack
end thisStackPath

on Import
if rect of fld "description" Γëá "258,116,509,336" then ZoomField
send "HideObjects" to this cd
show bg fld "source"
put FilePath("TEXT","Choose a file to import") into fName
if fName = empty then exit Import
go this cd
put empty into bg fld "source"
open file fName
repeat
read from file fName for 30000
if it = empty then exit repeat
put SubstituteChar(tab, "  ", it) after bg fld source
end repeat
show bg btn "source"
close file fName
end Import

function SubstituteChar origChar, newChar, container
--returns the given container with the original string
--substituted in all cases for the given new str.
repeat
set cursor to busy
put offset(origChar,container) into charPos
if charPos = 0 then return container
put newChar into char charPos of container
end repeat
end SubstituteChar

on UpdateMenu
-- update the menu on the first card
set lockscreen to true
set lockrecent to true
set lockmessages to true
put 0 into sourceCount
put empty into theList
go cd 1 of bg "examples"
repeat with cdNdx = 1 to the number of cds in this bg
set cursor to busy
go cd cdNdx of this bg
put the short name of this cd into theName
if bg fld "source" Γëá empty then
put " **" after theName
add 1 to sourceCount
end if
put the number of cds of this bg into total
put (the number of this cd - 1) into which
put which & "/" & total into bg fld "card count"
put theName & return after theList
end repeat
go cd 1
put theList into bg fld "list"
put sourceCount
unlock screen
end UpdateMenu

on CheckTitles
-- scan throught the card title fields to make sure I haven't left any
--  text in them (text is turned into bitmap to avoid ugly substituted
--  text on systems without the proper font)
lock screen
set lockrecent to true
set lockmessages to true
put empty into theErrors
go cd 1 of bg "examples"
repeat with cdNdx = 1 to the number of cds in this bg
set cursor to busy
go cd cdNdx of this bg
if bg fld "title" ≠ empty or bg fld "expl" ≠ empty then ¬
put the short id of this cd & "," after theErrors
end re